按一下车钥匙车门就开,门铃一按就响,这些“隔空操作”背后,十有八九是 433MHz 无线模块。它便宜到什么程度?一对发射加接收模块,常常不到两美元,算是最廉价的数据通信方案之一。国外创客网站 DroneBot Workshop 有一篇很经典的入门教程,把这对模块怎么接 Arduino 讲得很透,这篇照着它把要点理一遍,顺手替新手把容易卡住的坎标出来。
先说清楚:它跟前几天聊过的 NRF24L01 不是一回事。NRF24L01 是 2.4GHz 的双向收发芯片,能组双向链路,但配置折腾,还可能干扰路由器和无绳电话;433MHz 这对模块是单向通信,功能简单,胜在便宜省事。如果需求只是“这边发、那边收”,它就够用了。
先认识这俩模块

发射模块只有三个引脚:VCC、GND 和 DATA,VCC 从 3 到 12 伏都能吃;接收模块看着是四个引脚,中间两个内部连通,实际也是三根线:VCC、GND 和数据输出。有个细节要记住:发射端电压范围宽,接收端必须给 5 伏。两个模块都留了外接天线焊盘。
为什么这么便宜?因为它走量大,电子玩具、门铃、汽车钥匙里全是它。市面上那些 EV1527、PT2262 编码的成品遥控器,用的正是同一套 433MHz ASK 方案,手里有拆机的遥控钥匙,这对模块也能收到它发的信号。
合法性顺带提一句。各国对无执照射频发射都有规定,美国是 FCC 管,英国是 OFCOM 管。大多数国家对这类模块的要求是三条:功率低、间歇发射(发数字数据天然满足)、不传语音。拿不准就先查当地规定再动手。
ASK 调制和天线:17.3厘米要记牢
这对模块用的是 ASK,幅移键控,原理跟调幅广播一个思路:数据为 1 时载波全功率发出,数据为 0 时载波直接关断,只有两个电平。正因为电路简单,成本才压得下来;代价是抗干扰弱,容易被其他射频设备和背景噪声干扰。控制好发送速率,大多数环境能稳定工作。

天线决定通信距离,别嫌它土。不加天线,能通一米就算走运;有玩家反馈配好天线在户外开阔地能到 50 米。做法朴素:一根 22 或 24 号实心导线焊上天线焊盘即可,长度有讲究——433MHz 的波长是 69.24 厘米,取四分之一波长就是 17.3 厘米,这是最常用的值。嫌长可以绕着铅笔卷成弹簧状,体积小了,有时效率还更高。
实战一:把一句话发出去
第一个实验是把一条固定消息从发射端发到接收端,需要两块 Arduino,原教程用的是 Uno。发射端接线:VCC 接 5V,GND 接地,DATA 接 12 脚——12 脚是 RadioHead 库默认的数据输出脚,能不换就不换;天线焊盘上焊好那根 17.3 厘米导线。

接收端同样三根线:VCC 接 5V,GND 接地,数据输出接 11 脚。接收模块的天线焊盘常常没丝印,位置在模块左下角、小电感线圈旁边,别找错。

软件要用 RadioHead 库,Mike McCauley 为 Airspayce 写的公共领域代码,驱动各种射频设备,这里只用它的 ASK 部分。去 Airspayce 官网下载 ZIP 包,在 Arduino IDE 的“项目、导入库”菜单里选“添加 ZIP 库”装好,装完可能要重启 IDE。
发射端代码照原教程逐字搬运,只把尖括号头文件改成了引号写法,两种写法编译等价:
/*
433 MHz RF Module Transmitter Demonstration 1
RF-Xmit-Demo-1.ino
Demonstrates 433 MHz RF Transmitter Module
Use with Receiver Demonstration 1
DroneBot Workshop 2018
https://dronebotworkshop.com
*/
// Include RadioHead Amplitude Shift Keying Library
#include "RH_ASK.h"
// Include dependant SPI Library
#include "SPI.h"
// Create Amplitude Shift Keying Object
RH_ASK rf_driver;
void setup()
{
// Initialize ASK Object
rf_driver.init();
}
void loop()
{
const char *msg = "Welcome to the Workshop!";
rf_driver.send((uint8_t *)msg, strlen(msg));
rf_driver.waitPacketSent();
delay(1000);
}代码不长:建一个 RH_ASK 对象,setup 里 init(),loop 里把字符串发出去、waitPacketSent() 等发完,隔一秒再来一遍。注意消息"Welcome to the Workshop!"是 24 个字符,接收端要用到这个数。
接收端代码如下:
/*
433 MHz RF Module Receiver Demonstration 1
RF-Rcv-Demo-1.ino
Demonstrates 433 MHz RF Receiver Module
Use with Transmitter Demonstration 1
DroneBot Workshop 2018
https://dronebotworkshop.com
*/
// Include RadioHead Amplitude Shift Keying Library
#include "RH_ASK.h"
// Include dependant SPI Library
#include "SPI.h"
// Create Amplitude Shift Keying Object
RH_ASK rf_driver;
void setup()
{
// Initialize ASK Object
rf_driver.init();
// Setup Serial Monitor
Serial.begin(9600);
}
void loop()
{
// Set buffer to size of expected message
uint8_t buf[24];
uint8_t buflen = sizeof(buf);
// Check if received packet is correct size
if (rf_driver.recv(buf, &buflen))
{
// Message received with valid checksum
Serial.print("Message Received: ");
Serial.println((char*)buf);
}
}loop 里先开一个和消息等长的缓冲区 buf[24],rf_driver.recv() 收到校验通过的包就打印到串口。烧完代码打开串口监视器,9600 波特率,应该能看到这句话一遍遍刷出来。拿发射端在屋里走一圈,顺便就能试出天线和摆放方向的功力。
实战二:温湿度数据一起发
第二个实验实用得多:发射端加一个 DHT22 温湿度传感器,把读数发给接收端,适合测阁楼、地下室这种不方便拉线的位置。DHT22 四个引脚有一个空脚,VCC 并到发射模块同一组 5V 上,GND 接地,数据脚接 7 脚。要装 Adafruit 的 AM2315 库和 Unified Sensor 库,库管理器里搜名字就能装,后者是前者的依赖。

两个数值怎么一起发?原教程的做法是拼成“湿度,温度”格式的逗号分隔字符串发过去,接收端再拆开。发射端代码:
/*
433 MHz RF Module Transmitter Demonstration 2
RF-Xmit-Demo-2.ino
Demonstrates 433 MHz RF Transmitter Module with DHT-22 Sensor
Use with Receiver Demonstration 2
DroneBot Workshop 2018
https://dronebotworkshop.com
*/
// Include RadioHead Amplitude Shift Keying Library
#include "RH_ASK.h"
// Include dependant SPI Library
#include "SPI.h"
// Include DHT Libraries from Adafruit
// Dependant upon Adafruit_Sensors Library
#include "DHT.h";
// Define Constants
#define DHTPIN 7 // DHT-22 Output Pin connection
#define DHTTYPE DHT22 // DHT Type is DHT 22 (AM2302)
// Define Variables
float hum; // Stores humidity value in percent
float temp; // Stores temperature value in Celcius
// Define output strings
String str_humid;
String str_temp;
String str_out;
// Create Amplitude Shift Keying Object
RH_ASK rf_driver;
// Initialize DHT sensor for normal 16mhz Arduino
DHT dht(DHTPIN, DHTTYPE);
void setup() {
// Initialize ASK Object
rf_driver.init();
// Start DHT Sensor
dht.begin();
}
void loop()
{
delay(2000); // Delay so DHT-22 sensor can stabalize
hum = dht.readHumidity(); // Get Humidity value
temp= dht.readTemperature(); // Get Temperature value
// Convert Humidity to string
str_humid = String(hum);
// Convert Temperature to string
str_temp = String(temp);
// Combine Humidity and Temperature
str_out = str_humid + "," + str_temp;
// Compose output character
static char *msg = str_out.c_str();
rf_driver.send((uint8_t *)msg, strlen(msg));
rf_driver.waitPacketSent();
}loop 开头 delay(2000) 是给 DHT22 稳定的时间,然后读湿度温度、各自转成字符串、用逗号拼起来发送。接收端代码:
/*
433 MHz RF Module Receiver Demonstration 2
RF-Rcv-Demo-2.ino
Demonstrates 433 MHz RF Receiver Module with DHT-22 Sensor
Use with Transmitter Demonstration 2
DroneBot Workshop 2018
https://dronebotworkshop.com
*/
// Include RadioHead Amplitude Shift Keying Library
#include "RH_ASK.h"
// Include dependant SPI Library
#include "SPI.h"
// Define output strings
String str_humid;
String str_temp;
String str_out;
// Create Amplitude Shift Keying Object
RH_ASK rf_driver;
void setup()
{
// Initialize ASK Object
rf_driver.init();
// Setup Serial Monitor
Serial.begin(9600);
}
void loop()
{
// Set buffer to size of expected message
uint8_t buf[11];
uint8_t buflen = sizeof(buf);
// Check if received packet is correct size
if (rf_driver.recv(buf, &buflen))
{
// Message received with valid checksum
// Get values from string
// Convert received data into string
str_out = String((char*)buf);
// Split string into two values
for (int i = 0; i < str_out.length(); i++) {
if (str_out.substring(i, i+1) == ",") {
str_humid = str_out.substring(0, i);
str_temp = str_out.substring(i+1);
break;
}
}
// Print values to Serial Monitor
Serial.print("Humidity: ");
Serial.print(str_humid);
Serial.print(" - Temperature: ");
Serial.println(str_temp);
}
}接收端缓冲区改成 buf[11],收到后按逗号位置把字符串切成两段,分别打印。串口监视器里会按"Humidity: 湿度值 - Temperature: 温度值"的格式刷出来,拿发射端在家里不同位置测一圈,各处温湿度一目了然。数值后面偶尔跟一串乱码,其实是空字符,不是故障。
新手会卡在哪
高频翻车点列一下。一是接收端必须 5V,接低了收不到;二是 buf 尺寸必须和消息长度一致,空格标点都算字符,改了消息忘了改缓冲区就是白屏;三是引脚,发射 12、接收 11 是库默认值,非要换脚就得在 RH_ASK 构造函数里重新指定;四是天线别省,17.3 厘米这根线直接决定你能通多远。
想更进一步的话,逗号分隔这个思路可以扩到多路数据,把模拟输入值打包发过去做个无线摇杆也不难。前面提到的 EV1527 成品遥控器,用 RC Switch 库可以直接解码出按键值,接法跟这篇的接收端一样,感兴趣可以去翻它的示例程序。
总结:433MHz 这对模块是“单向、小数据”场景里性价比最高的选择,两块板、几根杜邦线、一根 17.3 厘米天线,就能给项目加上无线。它不炫技,但真能干活,这就是它在市场上长盛不衰的原因。











不到两美元一对,比蓝牙模块还便宜,学生党做课设的福音。
那个EV1527遥控器能用RC Switch解码的话,家里的无线门铃岂不是能接进Arduino了,回去试试。
接收板必须5V这个坑我也踩过,接3.3V死活没输出,换5V秒通。
17.3厘米这个数记住了,之前随手剪一段导线当天线,难怪只能隔一张桌子收到。
这套433MHz模块我拿来做过车库到屋里的温度回传,发射端挂一节9V电池放了小半年才换。印象最深的就是天线那段:一开始图省事没焊天线,隔着一条走廊就断断续续,后来照四分之一波长剪了17.3厘米导线焊上去,穿一堵墙都稳。再补一句,接收板尽量给独立的5V电源,我以前直接挂在UNO上,开关电源纹波一大就误码,串口里偶尔蹦乱码,换电源才消停。RadioHead库虽然重,但init之后send和recv确实省心,新手照着步骤走基本不翻车。